Visual Basic .NET - OLED 128x64 Bricklet

This is the description of the Visual Basic .NET API bindings for the OLED 128x64 Bricklet. General information and technical specifications for the OLED 128x64 Bricklet are summarized in its hardware description.

An installation guide for the Visual Basic .NET API bindings is part of their general description.

Examples

The example code below is Public Domain (CC0 1.0).

Hello World

Download (ExampleHelloWorld.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Imports System
Imports Tinkerforge

Module ExampleHelloWorld
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your OLED 128x64 Bricklet

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim oled As New BrickletOLED128x64(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Clear display
        oled.ClearDisplay()

        ' Write "Hello World" starting from upper left corner of the screen
        oled.WriteLine(0, 0, "Hello World")

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

Pixel Matrix

Download (ExamplePixelMatrix.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
Imports System
Imports System.Math
Imports Tinkerforge

Module ExamplePixelMatrix
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your OLED 128x64 Bricklet
    Const WIDTH As Integer = 128
    Const HEIGHT As Integer = 64

    Sub DrawMatrix(ByRef oled As BrickletOLED128x64, ByVal pixels()() As Boolean)
        Dim pages()() As Byte = New Byte(HEIGHT \ 8)() {}

        For row As Integer = 0 To HEIGHT \ 8 - 1
            pages(row) = New Byte(WIDTH) {}

            For column As Integer = 0 To WIDTH - 1
                pages(row)(column) = 0

                For bit As Integer = 0 To 7
                    If pixels((row * 8) + bit)(column) Then
                        pages(row)(column) = pages(row)(column) Or Convert.ToByte(1 << bit)
                    End If
                Next bit
            Next column
        Next row

        oled.NewWindow(0, WIDTH - 1, 0, HEIGHT \ 8 - 1)

        Dim section() As Byte = New Byte(64) {}

        For row As Integer = 0 To HEIGHT \ 8 - 1
            For column As Integer = 0 To WIDTH - 1 Step 64
                Array.Copy(pages(row), column, section, 0, 64)
                oled.Write(section)
            Next row
        Next row
    End Sub

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim oled As New BrickletOLED128x64(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Clear display
        oled.ClearDisplay()

        ' Draw checkerboard pattern
        Dim pixels()() As Boolean = New Boolean(HEIGHT)() {}

        For row As Integer = 0 To HEIGHT - 1
            pixels(row) = New Boolean(WIDTH) {}

            For column As Integer = 0 To WIDTH - 1
                pixels(row)(column) = (row \ 8) Mod 2 = (column \ 8) Mod 2
            Next row
        Next column

        DrawMatrix(oled, pixels)

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

Scribble

Download (ExampleScribble.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
Imports System
Imports System.Drawing
Imports System.Math
Imports System.Threading
Imports Tinkerforge

Module ExampleScribble
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change to your UID
    Const WIDTH As Integer = 128
    Const HEIGHT As Integer = 64

    Sub DrawImage(ByRef oled As BrickletOLED128x64, ByVal bitmap As Bitmap)
        Dim pages()() As Byte = New Byte(HEIGHT \ 8)() {}

        For row As Integer = 0 To HEIGHT \ 8 - 1
            pages(row) = New Byte(WIDTH) {}

            For column As Integer = 0 To WIDTH - 1
                pages(row)(column) = 0

                For bit As Integer = 0 To 7
                    If bitmap.GetPixel(column, (row * 8) + bit).GetBrightness() > 0 Then
                        pages(row)(column) = pages(row)(column) Or Convert.ToByte(1 << bit)
                    End If
                Next bit
            Next column
        Next row

        oled.NewWindow(0, WIDTH - 1, 0, HEIGHT \ 8 - 1)

        Dim section() As Byte = New Byte(64) {}

        For row As Integer = 0 To HEIGHT \ 8 - 1
            For column As Integer = 0 To WIDTH - 1 Step 64
                Array.Copy(pages(row), column, section, 0, 64)
                oled.Write(section)
            Next row
        Next row
    End Sub

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim oled As New BrickletOLED128x64(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Clear display
        oled.ClearDisplay()

        ' Draw rotating line
        Dim bitmap As New Bitmap(WIDTH, HEIGHT)
        Dim originX As Integer = WIDTH \ 2
        Dim originY As Integer = HEIGHT \ 2
        Dim length As Integer = HEIGHT \ 2 - 2
        Dim angle As Integer = 0

        Console.WriteLine("Press enter to exit")

        While Not Console.KeyAvailable
            Dim radians As Double = Math.PI * angle / 180.0
            Dim x As Integer = Convert.ToInt32(Math.Floor(originX + length * Math.Cos(radians)))
            Dim y As Integer = Convert.ToInt32(Math.Floor(originY + length * Math.Sin(radians)))

            Using g As Graphics = Graphics.FromImage(bitmap)
                g.FillRectangle(Brushes.Black, 0, 0, WIDTH, HEIGHT)
                g.DrawLine(Pens.White, originX, originY, x, y)
            End Using

            DrawImage(oled, bitmap)
            Thread.Sleep(25)

            angle += 1
        End While

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

API

Since Visual Basic .NET does not support multiple return values directly, we use the ByRef keyword to return multiple values from a function.

All functions and procedures listed below are thread-safe.

Basic Functions

Class BrickletOLED128x64(ByVal uid As String, ByVal ipcon As IPConnection)

Creates an object with the unique device ID uid:

Dim oled128x64 As New BrickletOLED128x64("YOUR_DEVICE_UID", ipcon)

This object can then be used after the IP Connection is connected (see examples above).

Sub BrickletOLED128x64.Write(ByVal data() As Byte)

Appends 64 byte of data to the window as set by NewWindow().

Each row has a height of 8 pixels which corresponds to one byte of data.

Example: if you call NewWindow() with column from 0 to 127 and row from 0 to 7 (the whole display) each call of Write() (red arrow) will write half of a row.

Display pixel order

The LSB (D0) of each data byte is at the top and the MSB (D7) is at the bottom of the row.

The next call of Write() will write the second half of the row and the next two the second row and so on. To fill the whole display you need to call Write() 16 times.

Sub BrickletOLED128x64.NewWindow(ByVal columnFrom As Byte, ByVal columnTo As Byte, ByVal rowFrom As Byte, ByVal rowTo As Byte)

Sets the window in which you can write with Write(). One row has a height of 8 pixels.

The columns have a range of 0 to 127 and the rows have a range of 0 to 7.

Sub BrickletOLED128x64.ClearDisplay()

Clears the current content of the window as set by NewWindow().

Sub BrickletOLED128x64.WriteLine(ByVal line As Byte, ByVal position As Byte, ByVal text As String)

Writes text to a specific line (0 to 7) with a specific position (0 to 25). The text can have a maximum of 26 characters.

For example: (1, 10, "Hello") will write Hello in the middle of the second line of the display.

You can draw to the display with Write() and then add text to it afterwards.

The display uses a special 5x7 pixel charset. You can view the characters of the charset in Brick Viewer.

Advanced Functions

Sub BrickletOLED128x64.SetDisplayConfiguration(ByVal contrast As Byte, ByVal invert As Boolean)

Sets the configuration of the display.

You can set a contrast value from 0 to 255 and you can invert the color (black/white) of the display.

The default values are contrast 143 and inverting off.

Sub BrickletOLED128x64.GetDisplayConfiguration(ByRef contrast As Byte, ByRef invert As Boolean)

Returns the configuration as set by SetDisplayConfiguration().

Function BrickletOLED128x64.GetAPIVersion() As Byte()

Returns the version of the API definition (major, minor, revision) implemented by this API bindings. This is neither the release version of this API bindings nor does it tell you anything about the represented Brick or Bricklet.

Function BrickletOLED128x64.GetResponseExpected(ByVal functionId As Byte) As Boolean

Returns the response expected flag for the function specified by the function ID parameter. It is true if the function is expected to send a response, false otherwise.

For getter functions this is enabled by default and cannot be disabled, because those functions will always send a response. For callback configuration functions it is enabled by default too, but can be disabled by SetResponseExpected(). For setter functions it is disabled by default and can be enabled.

Enabling the response expected flag for a setter function allows to detect timeouts and other error conditions calls of this setter as well. The device will then send a response for this purpose. If this flag is disabled for a setter function then no response is send and errors are silently ignored, because they cannot be detected.

See SetResponseExpected() for the list of function ID constants available for this function.

Sub BrickletOLED128x64.SetResponseExpected(ByVal functionId As Byte, ByVal responseExpected As Boolean)

Changes the response expected flag of the function specified by the function ID parameter. This flag can only be changed for setter (default value: false) and callback configuration functions (default value: true). For getter functions it is always enabled.

Enabling the response expected flag for a setter function allows to detect timeouts and other error conditions calls of this setter as well. The device will then send a response for this purpose. If this flag is disabled for a setter function then no response is send and errors are silently ignored, because they cannot be detected.

The following function ID constants are available for this function:

  • BrickletOLED128x64.FUNCTION_WRITE = 1
  • BrickletOLED128x64.FUNCTION_NEW_WINDOW = 2
  • BrickletOLED128x64.FUNCTION_CLEAR_DISPLAY = 3
  • BrickletOLED128x64.FUNCTION_SET_DISPLAY_CONFIGURATION = 4
  • BrickletOLED128x64.FUNCTION_WRITE_LINE = 6
Sub BrickletOLED128x64.SetResponseExpectedAll(ByVal responseExpected As Boolean)

Changes the response expected flag for all setter and callback configuration functions of this device at once.

Sub BrickletOLED128x64.GetIdentity(ByRef uid As String, ByRef connectedUid As String, ByRef position As Char, ByRef hardwareVersion() As Byte, ByRef firmwareVersion() As Byte, ByRef deviceIdentifier As Integer)

Returns the UID, the UID where the Bricklet is connected to, the position, the hardware and firmware version as well as the device identifier.

The position can be 'a', 'b', 'c' or 'd'.

The device identifier numbers can be found here. There is also a constant for the device identifier of this Bricklet.

Constants

Const BrickletOLED128x64.DEVICE_IDENTIFIER

This constant is used to identify a OLED 128x64 Bricklet.

The GetIdentity() function and the EnumerateCallback callback of the IP Connection have a deviceIdentifier parameter to specify the Brick's or Bricklet's type.

Const BrickletOLED128x64.DEVICE_DISPLAY_NAME

This constant represents the human readable name of a OLED 128x64 Bricklet.