Visual Basic .NET - LCD 20x4 Bricklet

This is the description of the Visual Basic .NET API bindings for the LCD 20x4 Bricklet. General information and technical specifications for the LCD 20x4 Bricklet are summarized in its hardware description.

An installation guide for the Visual Basic .NET API bindings is part of their general description.

Examples

The example code below is Public Domain (CC0 1.0).

Hello World

Download (ExampleHelloWorld.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Imports System
Imports Tinkerforge

Module ExampleHelloWorld
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your LCD 20x4 Bricklet

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim lcd As New BrickletLCD20x4(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Turn backlight on
        lcd.BacklightOn()

        ' Write "Hello World"
        lcd.WriteLine(0, 0, "Hello World")

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

Button Callback

Download (ExampleButtonCallback.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Imports System
Imports Tinkerforge

Module ExampleButtonCallback
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your LCD 20x4 Bricklet

    ' Callback subroutine for button pressed callback
    Sub ButtonPressedCB(ByVal sender As BrickletLCD20x4, ByVal button As Byte)
        Console.WriteLine("Button Pressed: " + button.ToString())
    End Sub

    ' Callback subroutine for button released callback
    Sub ButtonReleasedCB(ByVal sender As BrickletLCD20x4, ByVal button As Byte)
        Console.WriteLine("Button Released: " + button.ToString())
    End Sub

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim lcd As New BrickletLCD20x4(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Register button pressed callback to subroutine ButtonPressedCB
        AddHandler lcd.ButtonPressedCallback, AddressOf ButtonPressedCB

        ' Register button released callback to subroutine ButtonReleasedCB
        AddHandler lcd.ButtonReleasedCallback, AddressOf ButtonReleasedCB

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

Unicode

Download (ExampleUnicode.vb)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
Imports System
Imports Tinkerforge

Module ExampleUnicode
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your LCD 20x4 Bricklet

    ' Maps a normal UTF-16 encoded string to the LCD charset
    Function UTF16ToKS0066U(ByVal utf16 As String) As String
        Dim ks0066u As String = ""
        Dim c As Char
        Dim i As Integer = 0

        While i < utf16.Length
            Dim codePoint As Integer = Char.ConvertToUtf32(utf16, i)

            if Char.IsSurrogate(utf16, i) Then
                ' Skip low surrogate
                i += 1
            End If

            ' ASCII subset from JIS X 0201
            if (codePoint >= &H0020) And (codePoint <= &H007e) Then
                ' The LCD charset doesn't include '\' and '~', use similar characters instead
                Select Case codePoint
                    Case &H005c
                        c = Chr(&H00a4) ' REVERSE SOLIDUS maps to IDEOGRAPHIC COMMA
                    Case &H007e
                        c = Chr(&H002d) ' TILDE maps to HYPHEN-MINUS
                    Case Else
                        c = Chr(codePoint)
                End Select
            ' Katakana subset from JIS X 0201
            Else If (codePoint >= &Hff61) And (codePoint <= &Hff9f) Then
                c = Chr(codePoint - &Hfec0)
            ' Special characters
            Else
                Select Case codePoint
                    Case &H00a5
                        c = Chr(&H5c) ' YEN SIGN
                    Case &H2192
                        c = Chr(&H7e) ' RIGHTWARDS ARROW
                    Case &H2190
                        c = Chr(&H7f) ' LEFTWARDS ARROW
                    Case &H00b0
                        c = Chr(&Hdf) ' DEGREE SIGN maps to KATAKANA SEMI-VOICED SOUND MARK
                    Case &H03b1
                        c = Chr(&He0) ' GREEK SMALL LETTER ALPHA
                    Case &H00c4
                        c = Chr(&He1) ' LATIN CAPITAL LETTER A WITH DIAERESIS
                    Case &H00e4
                        c = Chr(&He1) ' LATIN SMALL LETTER A WITH DIAERESIS
                    Case &H00df
                        c = Chr(&He2) ' LATIN SMALL LETTER SHARP S
                    Case &H03b5
                        c = Chr(&He3) ' GREEK SMALL LETTER EPSILON
                    Case &H00b5
                        c = Chr(&He4) ' MICRO SIGN
                    Case &H03bc
                        c = Chr(&He4) ' GREEK SMALL LETTER MU
                    Case &H03c2
                        c = Chr(&He5) ' GREEK SMALL LETTER FINAL SIGMA
                    Case &H03c1
                        c = Chr(&He6) ' GREEK SMALL LETTER RHO
                    Case &H221a
                        c = Chr(&He8) ' SQUARE ROOT
                    Case &H00b9
                        c = Chr(&He9) ' SUPERSCRIPT ONE maps to SUPERSCRIPT (minus) ONE
                    Case &H00a4
                        c = Chr(&Heb) ' CURRENCY SIGN
                    Case &H00a2
                        c = Chr(&Hec) ' CENT SIGN
                    Case &H2c60
                        c = Chr(&Hed) ' LATIN CAPITAL LETTER L WITH DOUBLE BAR
                    Case &H00f1
                        c = Chr(&Hee) ' LATIN SMALL LETTER N WITH TILDE
                    Case &H00d6
                        c = Chr(&Hef) ' LATIN CAPITAL LETTER O WITH DIAERESIS
                    Case &H00f6
                        c = Chr(&Hef) ' LATIN SMALL LETTER O WITH DIAERESIS
                    Case &H03f4
                        c = Chr(&Hf2) ' GREEK CAPITAL THETA SYMBOL
                    Case &H221e
                        c = Chr(&Hf3) ' INFINITY
                    Case &H03a9
                        c = Chr(&Hf4) ' GREEK CAPITAL LETTER OMEGA
                    Case &H00dc
                        c = Chr(&Hf5) ' LATIN CAPITAL LETTER U WITH DIAERESIS
                    Case &H00fc
                        c = Chr(&Hf5) ' LATIN SMALL LETTER U WITH DIAERESIS
                    Case &H03a3
                        c = Chr(&Hf6) ' GREEK CAPITAL LETTER SIGMA
                    Case &H03c0
                        c = Chr(&Hf7) ' GREEK SMALL LETTER PI
                    Case &H0304
                        c = Chr(&Hf8) ' COMBINING MACRON
                    Case &H00f7
                        c = Chr(&Hfd) ' DIVISION SIGN
                    Case &H25a0
                        c = Chr(&Hff) ' BLACK SQUARE
                    Case Else
                        c = Chr(&Hff) ' BLACK SQUARE
                End Select
            End If

            ' Special handling for 'x' followed by COMBINING MACRON
            If c = Chr(&Hf8) Then
                If Not ks0066u.EndsWith("x") Then
                    c = Chr(&Hff) ' BLACK SQUARE
                End If

                If ks0066u.Length > 0 Then
                    ks0066u = ks0066u.Remove(ks0066u.Length - 1, 1)
                End If
            End If

            ks0066u += c
            i += 1
        End While

        Return ks0066u
    End Function

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim lcd As New BrickletLCD20x4(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Turn backlight on
        lcd.BacklightOn()

        ' Write some strings using the UTF16ToKS0066U function to map to the LCD charset
        lcd.WriteLine(0, 0, UTF16ToKS0066U("Stromstärke: 17µA"))
        lcd.WriteLine(1, 0, UTF16ToKS0066U("Temperatur:  23°C"))

        ' Write a string directly including characters from the LCD charset
        lcd.WriteLine(2, 0, "Drehzahl:   750min" + Chr(&He9))

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

API

Since Visual Basic .NET does not support multiple return values directly, we use the ByRef keyword to return multiple values from a function.

All functions and procedures listed below are thread-safe.

Basic Functions

Class BrickletLCD20x4(ByVal uid As String, ByVal ipcon As IPConnection)

Creates an object with the unique device ID uid:

Dim lcd20x4 As New BrickletLCD20x4("YOUR_DEVICE_UID", ipcon)

This object can then be used after the IP Connection is connected (see examples above).

Sub BrickletLCD20x4.WriteLine(ByVal line As Byte, ByVal position As Byte, ByVal text As String)

Writes text to a specific line (0 to 3) with a specific position (0 to 19). The text can have a maximum of 20 characters.

For example: (0, 7, "Hello") will write Hello in the middle of the first line of the display.

The display uses a special charset that includes all ASCII characters except backslash and tilde. The LCD charset also includes several other non-ASCII characters, see the charset specification for details. The Unicode example above shows how to specify non-ASCII characters and how to translate from Unicode to the LCD charset.

Sub BrickletLCD20x4.ClearDisplay()

Deletes all characters from the display.

Sub BrickletLCD20x4.BacklightOn()

Turns the backlight on.

Sub BrickletLCD20x4.BacklightOff()

Turns the backlight off.

Function BrickletLCD20x4.IsBacklightOn() As Boolean

Returns true if the backlight is on and false otherwise.

Advanced Functions

Sub BrickletLCD20x4.SetConfig(ByVal cursor As Boolean, ByVal blinking As Boolean)

Configures if the cursor (shown as "_") should be visible and if it should be blinking (shown as a blinking block). The cursor position is one character behind the the last text written with WriteLine().

The default is (false, false).

Sub BrickletLCD20x4.GetConfig(ByRef cursor As Boolean, ByRef blinking As Boolean)

Returns the configuration as set by SetConfig().

Function BrickletLCD20x4.IsButtonPressed(ByVal button As Byte) As Boolean

Returns true if the button (0 to 2 or 0 to 3 since hardware version 1.2) is pressed.

If you want to react on button presses and releases it is recommended to use the ButtonPressedCallback and ButtonReleasedCallback callbacks.

Sub BrickletLCD20x4.SetCustomCharacter(ByVal index As Byte, ByVal character() As Byte)

The LCD 20x4 Bricklet can store up to 8 custom characters. The characters consist of 5x8 pixels and can be addressed with the index 0-7. To describe the pixels, the first 5 bits of 8 bytes are used. For example, to make a custom character "H", you should transfer the following:

  • character[0] = 0b00010001 (decimal value 17)
  • character[1] = 0b00010001 (decimal value 17)
  • character[2] = 0b00010001 (decimal value 17)
  • character[3] = 0b00011111 (decimal value 31)
  • character[4] = 0b00010001 (decimal value 17)
  • character[5] = 0b00010001 (decimal value 17)
  • character[6] = 0b00010001 (decimal value 17)
  • character[7] = 0b00000000 (decimal value 0)

The characters can later be written with WriteLine() by using the characters with the byte representation 8 ("x08") to 15 ("x0F").

You can play around with the custom characters in Brick Viewer version since 2.0.1.

Custom characters are stored by the LCD in RAM, so they have to be set after each startup.

New in version 2.0.1 (Plugin).

Function BrickletLCD20x4.GetCustomCharacter(ByVal index As Byte) As Byte()

Returns the custom character for a given index, as set with SetCustomCharacter().

New in version 2.0.1 (Plugin).

Sub BrickletLCD20x4.SetDefaultText(ByVal line As Byte, ByVal text As String)

Sets the default text for lines 0-3. The max number of characters per line is 20.

The default text is shown on the LCD, if the default text counter expires, see SetDefaultTextCounter().

New in version 2.0.2 (Plugin).

Function BrickletLCD20x4.GetDefaultText(ByVal line As Byte) As String

Returns the default text for a given line (0-3) as set by SetDefaultText().

New in version 2.0.2 (Plugin).

Sub BrickletLCD20x4.SetDefaultTextCounter(ByVal counter As Integer)

Sets the default text counter in ms. This counter is decremented each ms by the LCD firmware. If the counter reaches 0, the default text (see SetDefaultText()) is shown on the LCD.

This functionality can be used to show a default text if the controlling program crashes or the connection is interrupted.

A possible approach is to call SetDefaultTextCounter() every minute with the parameter 1000*60*2 (2 minutes). In this case the default text will be shown no later than 2 minutes after the controlling program crashes.

A negative counter turns the default text functionality off.

The default is -1.

New in version 2.0.2 (Plugin).

Function BrickletLCD20x4.GetDefaultTextCounter() As Integer

Returns the current value of the default text counter.

New in version 2.0.2 (Plugin).

Function BrickletLCD20x4.GetAPIVersion() As Byte()

Returns the version of the API definition (major, minor, revision) implemented by this API bindings. This is neither the release version of this API bindings nor does it tell you anything about the represented Brick or Bricklet.

Function BrickletLCD20x4.GetResponseExpected(ByVal functionId As Byte) As Boolean

Returns the response expected flag for the function specified by the function ID parameter. It is true if the function is expected to send a response, false otherwise.

For getter functions this is enabled by default and cannot be disabled, because those functions will always send a response. For callback configuration functions it is enabled by default too, but can be disabled by SetResponseExpected(). For setter functions it is disabled by default and can be enabled.

Enabling the response expected flag for a setter function allows to detect timeouts and other error conditions calls of this setter as well. The device will then send a response for this purpose. If this flag is disabled for a setter function then no response is send and errors are silently ignored, because they cannot be detected.

See SetResponseExpected() for the list of function ID constants available for this function.

Sub BrickletLCD20x4.SetResponseExpected(ByVal functionId As Byte, ByVal responseExpected As Boolean)

Changes the response expected flag of the function specified by the function ID parameter. This flag can only be changed for setter (default value: false) and callback configuration functions (default value: true). For getter functions it is always enabled.

Enabling the response expected flag for a setter function allows to detect timeouts and other error conditions calls of this setter as well. The device will then send a response for this purpose. If this flag is disabled for a setter function then no response is send and errors are silently ignored, because they cannot be detected.

The following function ID constants are available for this function:

  • BrickletLCD20x4.FUNCTION_WRITE_LINE = 1
  • BrickletLCD20x4.FUNCTION_CLEAR_DISPLAY = 2
  • BrickletLCD20x4.FUNCTION_BACKLIGHT_ON = 3
  • BrickletLCD20x4.FUNCTION_BACKLIGHT_OFF = 4
  • BrickletLCD20x4.FUNCTION_SET_CONFIG = 6
  • BrickletLCD20x4.FUNCTION_SET_CUSTOM_CHARACTER = 11
  • BrickletLCD20x4.FUNCTION_SET_DEFAULT_TEXT = 13
  • BrickletLCD20x4.FUNCTION_SET_DEFAULT_TEXT_COUNTER = 15
Sub BrickletLCD20x4.SetResponseExpectedAll(ByVal responseExpected As Boolean)

Changes the response expected flag for all setter and callback configuration functions of this device at once.

Sub BrickletLCD20x4.GetIdentity(ByRef uid As String, ByRef connectedUid As String, ByRef position As Char, ByRef hardwareVersion() As Byte, ByRef firmwareVersion() As Byte, ByRef deviceIdentifier As Integer)

Returns the UID, the UID where the Bricklet is connected to, the position, the hardware and firmware version as well as the device identifier.

The position can be 'a', 'b', 'c' or 'd'.

The device identifier numbers can be found here. There is also a constant for the device identifier of this Bricklet.

Callbacks

Callbacks can be registered to receive time critical or recurring data from the device. The registration is done by assigning a procedure to an callback property of the device object:

Sub MyCallback(ByVal sender As BrickletLCD20x4, ByVal value As Short)
    Console.WriteLine("Value: {0}", value)
End Sub

AddHandler lcd20x4.ExampleCallback, AddressOf MyCallback

The available callback property and their type of parameters are described below.

Note

Using callbacks for recurring events is always preferred compared to using getters. It will use less USB bandwidth and the latency will be a lot better, since there is no round trip time.

Event BrickletLCD20x4.ButtonPressedCallback(ByVal sender As BrickletLCD20x4, ByVal button As Byte)

This callback is triggered when a button is pressed. The parameter is the number of the button (0 to 2 or 0 to 3 since hardware version 1.2).

Event BrickletLCD20x4.ButtonReleasedCallback(ByVal sender As BrickletLCD20x4, ByVal button As Byte)

This callback is triggered when a button is released. The parameter is the number of the button (0 to 2 or 0 to 3 since hardware version 1.2).

Constants

Const BrickletLCD20x4.DEVICE_IDENTIFIER

This constant is used to identify a LCD 20x4 Bricklet.

The GetIdentity() function and the EnumerateCallback callback of the IP Connection have a deviceIdentifier parameter to specify the Brick's or Bricklet's type.

Const BrickletLCD20x4.DEVICE_DISPLAY_NAME

This constant represents the human readable name of a LCD 20x4 Bricklet.