Visual Basic .NET - OLED 64x48 Bricklet

Dies ist die Beschreibung der Visual Basic .NET API Bindings für das OLED 64x48 Bricklet. Allgemeine Informationen über die Funktionen und technischen Spezifikationen des OLED 64x48 Bricklet sind in dessen Hardware Beschreibung zusammengefasst.

Eine Installationanleitung für die Visual Basic .NET API Bindings ist Teil deren allgemeine Beschreibung.

Beispiele

Der folgende Beispielcode ist Public Domain (CC0 1.0).

Hello World

Download (ExampleHelloWorld.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Imports System
Imports Tinkerforge

Module ExampleHelloWorld
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your OLED 64x48 Bricklet

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim oled As New BrickletOLED64x48(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Clear display
        oled.ClearDisplay()

        ' Write "Hello World" starting from upper left corner of the screen
        oled.WriteLine(0, 0, "Hello World")

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

Pixel Matrix

Download (ExamplePixelMatrix.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
Imports System
Imports System.Math
Imports Tinkerforge

Module ExamplePixelMatrix
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change XYZ to the UID of your OLED 64x48 Bricklet
    Const WIDTH As Integer = 64
    Const HEIGHT As Integer = 48

    Sub DrawMatrix(ByRef oled As BrickletOLED64x48, ByVal pixels()() As Boolean)
        Dim pages()() As Byte = New Byte(HEIGHT \ 8)() {}

        For row As Integer = 0 To HEIGHT \ 8 - 1
            pages(row) = New Byte(WIDTH) {}

            For column As Integer = 0 To WIDTH - 1
                pages(row)(column) = 0

                For bit As Integer = 0 To 7
                    If pixels((row * 8) + bit)(column) Then
                        pages(row)(column) = pages(row)(column) Or Convert.ToByte(1 << bit)
                    End If
                Next bit
            Next column
        Next row

        oled.NewWindow(0, WIDTH - 1, 0, HEIGHT \ 8 - 1)

        For row As Integer = 0 To HEIGHT \ 8 - 1
            oled.Write(pages(row))
        Next
    End Sub

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim oled As New BrickletOLED64x48(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Clear display
        oled.ClearDisplay()

        ' Draw checkerboard pattern
        Dim pixels()() As Boolean = New Boolean(HEIGHT)() {}

        For row As Integer = 0 To HEIGHT - 1
            pixels(row) = New Boolean(WIDTH) {}

            For column As Integer = 0 To WIDTH - 1
                pixels(row)(column) = (row \ 8) Mod 2 = (column \ 8) Mod 2
            Next row
        Next column

        DrawMatrix(oled, pixels)

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

Scribble

Download (ExampleScribble.vb)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Imports System
Imports System.Drawing
Imports System.Math
Imports System.Threading
Imports Tinkerforge

Module ExampleScribble
    Const HOST As String = "localhost"
    Const PORT As Integer = 4223
    Const UID As String = "XYZ" ' Change to your UID
    Const WIDTH As Integer = 64
    Const HEIGHT As Integer = 48

    Sub DrawImage(ByRef oled As BrickletOLED64x48, ByVal bitmap As Bitmap)
        Dim pages()() As Byte = New Byte(HEIGHT \ 8)() {}

        For row As Integer = 0 To HEIGHT \ 8 - 1
            pages(row) = New Byte(WIDTH) {}

            For column As Integer = 0 To WIDTH - 1
                pages(row)(column) = 0

                For bit As Integer = 0 To 7
                    If bitmap.GetPixel(column, (row * 8) + bit).GetBrightness() > 0 Then
                        pages(row)(column) = pages(row)(column) Or Convert.ToByte(1 << bit)
                    End If
                Next bit
            Next column
        Next row

        oled.NewWindow(0, WIDTH - 1, 0, HEIGHT \ 8 - 1)

        For row As Integer = 0 To HEIGHT \ 8 - 1
            oled.Write(pages(row))
        Next
    End Sub

    Sub Main()
        Dim ipcon As New IPConnection() ' Create IP connection
        Dim oled As New BrickletOLED64x48(UID, ipcon) ' Create device object

        ipcon.Connect(HOST, PORT) ' Connect to brickd
        ' Don't use device before ipcon is connected

        ' Clear display
        oled.ClearDisplay()

        ' Draw rotating line
        Dim bitmap As New Bitmap(WIDTH, HEIGHT)
        Dim originX As Integer = WIDTH \ 2
        Dim originY As Integer = HEIGHT \ 2
        Dim length As Integer = HEIGHT \ 2 - 2
        Dim angle As Integer = 0

        Console.WriteLine("Press enter to exit")

        While Not Console.KeyAvailable
            Dim radians As Double = Math.PI * angle / 180.0
            Dim x As Integer = Convert.ToInt32(Math.Floor(originX + length * Math.Cos(radians)))
            Dim y As Integer = Convert.ToInt32(Math.Floor(originY + length * Math.Sin(radians)))

            Using g As Graphics = Graphics.FromImage(bitmap)
                g.FillRectangle(Brushes.Black, 0, 0, WIDTH, HEIGHT)
                g.DrawLine(Pens.White, originX, originY, x, y)
            End Using

            DrawImage(oled, bitmap)
            Thread.Sleep(25)

            angle += 1
        End While

        Console.WriteLine("Press key to exit")
        Console.ReadLine()
        ipcon.Disconnect()
    End Sub
End Module

API

Da Visual Basic .NET nicht mehrere Rückgabewerte direkt unterstützt, wird das ByRef Schlüsselwort genutzt um mehrere Werte von einer Funktion zurückzugeben.

Alle folgend aufgelisteten Funktionen und Prozeduren sind Thread-sicher.

Grundfunktionen

Class BrickletOLED64x48(ByVal uid As String, ByVal ipcon As IPConnection)

Erzeugt ein Objekt mit der eindeutigen Geräte ID uid:

Dim oled64x48 As New BrickletOLED64x48("YOUR_DEVICE_UID", ipcon)

Dieses Objekt kann benutzt werden, nachdem die IP Connection verbunden ist (siehe Beispiele oben).

Sub BrickletOLED64x48.Write(ByVal data() As Byte)

Fügt 64 Byte Daten zu dem mit NewWindow() gesetztem Fenster hinzu.

Jede Zeile hat eine Höhe von 8 Pixeln welche einem Byte Daten entsprechen.

Beispiel: Wenn NewWindow() mit Spalte (Column) von 0 bis 63 und Zeile (Row) von 0 bis 5 (das ganze Display) aufgerufen wird, schreibt jedes Write() (roter Pfeil) eine Zeile.

Display Pixel Reihenfolge

Das LSB (D0) von jedem Daten-Byte ist in der Zeile oben und das MSB (D7) ist in der Zeile unten.

Der nächste Aufruf von Write() schreibt die zweite Zeile usw. Um das ganze Display zu füllen muss Write() 6 mal aufgerufen werden.

Sub BrickletOLED64x48.NewWindow(ByVal columnFrom As Byte, ByVal columnTo As Byte, ByVal rowFrom As Byte, ByVal rowTo As Byte)

Setzt das Fenster in welches mit Write() geschrieben werden kann. Eine Zeile (Row) hat eine Höhe von 8 Pixel.

Die Spalten haben einen Wertebereich von 0 bis 63 und die Zeilen haben einen Wertebereich von 0 bis 5.

Sub BrickletOLED64x48.ClearDisplay()

Löscht den aktuellen Inhalt des mit NewWindow() gesetztem Fensters.

Sub BrickletOLED64x48.WriteLine(ByVal line As Byte, ByVal position As Byte, ByVal text As String)

Schreibt einen Text in die angegebene Zeile (0 bis 5) mit einer vorgegebenen Position (0 bis 12). Der Text kann maximal 13 Zeichen lang sein.

Beispiel: (1, 4, "Hallo") schreibt Hallo in die Mitte der zweiten Zeile des Displays.

Es ist möglich zuerst auf das Display mit Write() zu malen und danach Text hinzuzufügen.

Das Display nutzt einen speziellen 5x7 Pixel Zeichensatz. Der Zeichensatz kann mit Hilfe von Brick Viewer angezeigt werden.

Fortgeschrittene Funktionen

Sub BrickletOLED64x48.SetDisplayConfiguration(ByVal contrast As Byte, ByVal invert As Boolean)

Setzt die Konfiguration des Displays

Es können der Kontrast mit einem Wertebereich von 0 bis 255 gesetzt, sowie die Farben (schwarz/weiß) des Displays invertiert werden.

Die Standardwerte sind ein Kontrast von 143 und die Invertierung ist aus.

Sub BrickletOLED64x48.GetDisplayConfiguration(ByRef contrast As Byte, ByRef invert As Boolean)

Gibt die Konfiguration zurück, wie von SetDisplayConfiguration() gesetzt.

Function BrickletOLED64x48.GetAPIVersion() As Byte()

Gibt die Version der API Definition (Major, Minor, Revision) zurück, die diese API Bindings implementieren. Dies ist weder die Release-Version dieser API Bindings noch gibt es in irgendeiner Weise Auskunft über den oder das repräsentierte(n) Brick oder Bricklet.

Function BrickletOLED64x48.GetResponseExpected(ByVal functionId As Byte) As Boolean

Gibt das Response-Expected-Flag für die Funktion mit der angegebenen Funktions IDs zurück. Es ist true falls für die Funktion beim Aufruf eine Antwort erwartet wird, false andernfalls.

Für Getter-Funktionen ist diese Flag immer gesetzt und kann nicht entfernt werden, da diese Funktionen immer eine Antwort senden. Für Konfigurationsfunktionen für Callbacks ist es standardmäßig gesetzt, kann aber entfernt werden mittels SetResponseExpected(). Für Setter-Funktionen ist es standardmäßig nicht gesetzt, kann aber gesetzt werden.

Wenn das Response-Expected-Flag für eine Setter-Funktion gesetzt ist, können Timeouts und andere Fehlerfälle auch für Aufrufe dieser Setter-Funktion detektiert werden. Das Gerät sendet dann eine Antwort extra für diesen Zweck. Wenn das Flag für eine Setter-Funktion nicht gesetzt ist, dann wird keine Antwort vom Gerät gesendet und Fehler werden stillschweigend ignoriert, da sie nicht detektiert werden können.

Siehe SetResponseExpected() für die Liste der verfügbaren Funktions ID Konstanten für diese Funktion.

Sub BrickletOLED64x48.SetResponseExpected(ByVal functionId As Byte, ByVal responseExpected As Boolean)

Ändert das Response-Expected-Flag für die Funktion mit der angegebenen Funktion IDs. Diese Flag kann nur für Setter-Funktionen (Standardwert: false) und Konfigurationsfunktionen für Callbacks (Standardwert: true) geändert werden. Für Getter-Funktionen ist das Flag immer gesetzt.

Wenn das Response-Expected-Flag für eine Setter-Funktion gesetzt ist, können Timeouts und andere Fehlerfälle auch für Aufrufe dieser Setter-Funktion detektiert werden. Das Gerät sendet dann eine Antwort extra für diesen Zweck. Wenn das Flag für eine Setter-Funktion nicht gesetzt ist, dann wird keine Antwort vom Gerät gesendet und Fehler werden stillschweigend ignoriert, da sie nicht detektiert werden können.

Die folgenden Funktions ID Konstanten sind für diese Funktion verfügbar:

  • BrickletOLED64x48.FUNCTION_WRITE = 1
  • BrickletOLED64x48.FUNCTION_NEW_WINDOW = 2
  • BrickletOLED64x48.FUNCTION_CLEAR_DISPLAY = 3
  • BrickletOLED64x48.FUNCTION_SET_DISPLAY_CONFIGURATION = 4
  • BrickletOLED64x48.FUNCTION_WRITE_LINE = 6
Sub BrickletOLED64x48.SetResponseExpectedAll(ByVal responseExpected As Boolean)

Ändert das Response-Expected-Flag für alle Setter-Funktionen und Konfigurationsfunktionen für Callbacks diese Gerätes.

Sub BrickletOLED64x48.GetIdentity(ByRef uid As String, ByRef connectedUid As String, ByRef position As Char, ByRef hardwareVersion() As Byte, ByRef firmwareVersion() As Byte, ByRef deviceIdentifier As Integer)

Gibt die UID, die UID zu der das Bricklet verbunden ist, die Position, die Hard- und Firmware Version sowie den Device Identifier zurück.

Die Position kann 'a', 'b', 'c' oder 'd' sein.

Eine Liste der Device Identifier Werte ist hier zu finden. Es gibt auch eine Konstante für den Device Identifier dieses Bricklets.

Konstanten

Const BrickletOLED64x48.DEVICE_IDENTIFIER

Diese Konstante wird verwendet um ein OLED 64x48 Bricklet zu identifizieren.

Die GetIdentity() Funktion und der EnumerateCallback Callback der IP Connection haben ein deviceIdentifier Parameter um den Typ des Bricks oder Bricklets anzugeben.

Const BrickletOLED64x48.DEVICE_DISPLAY_NAME

Diese Konstante stellt den Anzeigenamen eines OLED 64x48 Bricklet dar.